pro movisPlotSingle, name, class, covar, data, range=range, label=label

  cgPS_open, Filename=Name, /metric, /decomposed, /encapsulated, $
             xSize=15, ySize=15, language_level=2, /quiet

;help,  name, class, covar, data
;help,  name, class, covar, data,/str



  ccTickInt= [0.2, 0.2, 0.2, 0.2, 0.2, 0.1 ]
  ccTickMin= [ 4 ,  4 ,  4 ,  4 ,  4 ,  4  ]
  
  k1 = 0
  k2 = 1


  nbClass = n_elements(class)
  nbComb  =n_elements(label)
  theta=2*!PI*findgen(361)/360

 ;--III.5.3--Prepare Plot OutLay
  xRang = range[*,k1]
  yRang = range[*,k2]
  cgPlot, 0,0, /NoData, charsize=1, $
          xStyle=1, xRange=xRang, xTitle=label[k1], $
          yStyle=1, yRange=yRang, yTitle=label[k2], $
          xTickInt=ccTickInt[k1], xMinor=ccTickMin[k1], $
          yTickInt=ccTickInt[k2], yMinor=ccTickMin[k2]


 ;--III.5.4--Plot Each Object within the Class
  for kClass=0, nbClass-1 do begin
    cur=where( strcmp(data.class,class[kClass].label) )
    cgPlot, /OverPlot, data[cur].col[k1], data[cur].col[k2], $
            psym=class[kClass].sym, color=class[kClass].color, symSize=class[kClass].size
  endfor

 ;--III.5.5--Plot Cross + Ellipse for each Class
  for kClass=0, nbClass-1 do begin

   ;--III.4.5/A--Long-Axis Line
    xA = [-1,1]*covar[kClass].stdA
    yA = [0,0]

    rotXA = xA*covar[kClass].cos - yA*covar[kClass].sin + covar[kClass].meanX
    rotYA = xA*covar[kClass].sin + yA*covar[kClass].cos + covar[kClass].meanY
    cgPlot, rotXA, rotYA, color=class[kClass].color, /OverPlot
    
   ;--III.4.5/B--Short-Axis Line
    xB = [0,0]
    yB = [-1,1]*covar[kClass].stdB

    rotXB = xB*covar[kClass].cos - yB*covar[kClass].sin + covar[kClass].meanX
    rotYB = xB*covar[kClass].sin + yB*covar[kClass].cos + covar[kClass].meanY
    cgPlot, rotXB, rotYB, color=class[kClass].color, /OverPlot

   ;--III.4.5/C--Ellipse
    x = covar[kClass].stdA * cos(theta)
    y = covar[kClass].stdB * sin(theta)

    rotX = x*covar[kClass].cos - y*covar[kClass].sin + covar[kClass].meanX
    rotY = x*covar[kClass].sin + y*covar[kClass].cos + covar[kClass].meanY
    
    cgPlot, rotX, rotY, color=class[kClass].color, /OverPlot
    cgText, covar[kClass].meanX + 0.3*covar[kClass].stdX, $
            covar[kClass].meanY + 0.3*covar[kClass].stdY, class[kClass].label, color=class[kClass].color
    
 endfor

  cgPS_close, /png, Delete_PS=0



end