; docformat = 'rst'
;
; NAME:
;    K2GetTarget
; PURPOSE:
;    Download all the Target Pixel Data from a K2 Campaign
;
;+
; :Description:
;    Download all the Target Pixel Data from a K2 Campaign
;    
; :Categories:
;    K2
;    
; :Params:
;    campaign: in, required, type=float/string
;        The K2 Campaign number (e.g., 0, 1, 2, '9a', '9b', 10...)
;
; :Keywords:
;    init: in, optional, type=string, default='~/.idl/k2/ini'
;      Path to the K2 configuration file
;    verbose: in, optional, type=boolean, default=0
;      Verbose progression to stdout
;
; :Examples:
;    Get all the Target Pixel Data files from Campaign 0::
;      IDL> K2GetTarget, 0
;
; :Uses:
;    K2Init, K2ReadTarget
;
; :Author:
;    B.Carry (OCA)
;
; :History:
;    Change History::
;      Created in July 2016 by B. Carry (OCA)
;-
pro K2GetTarget, campaign, init=init, verbose=verbose

   
;-----------------------------------------------------------------------------------------------;
;-----------------------------------------------------------------------------------------------;
;---  TAG ---    I -- Initialization And Input Verification              -----------------------;
;-----------------------------------------------------------------------------------------------;
;-----------------------------------------------------------------------------------------------;
  COMPILE_OPT hidden, idl2

 ;--I.1-- Input checks  ------------------------------------------------------------------------
  if not keyword_set(campaign) and n_elements(campaign) eq 0 then return
  if keyword_set(init) then conf=K2Init(init) else conf=K2Init()

 ;--I.2-- Campaign Labels  ---------------------------------------------------------------------
  dimC = size(campaign)
  if dimC[dimC[0]+1] eq 2 then begin
    campLoLab1 = 'c'+strTrim(string(campaign,format='(I)'),2)
    campUpLab1 = 'C'+strTrim(string(campaign,format='(I)'),2)
    campLoLab2 = 'c'+strTrim(string(campaign,format='(I02)'),2)
    campUpLab2 = 'C'+strTrim(string(campaign,format='(I02)'),2)
  endif else begin
    campLoLab1 = 'c'+strTrim(campaign,2)
    campUpLab1 = 'C'+strTrim(campaign,2)
    campLoLab2 = 'c'+strTrim(campaign,2)
    campUpLab2 = 'C'+strTrim(campaign,2)
  endelse


 ;--I.3-- Directories  -------------------------------------------------------------------------
  dirFITS = conf.path.root+conf.path.target+campUpLab1+'/'
  if not file_test(dirFITS,/Directory) then file_mkdir, dirFITS


 ;--I.4-- Preferences  -------------------------------------------------------------------------
  if conf.user.verbose eq 1 then verbose=1


 ;--I.5-- List of EPIC To Download  ------------------------------------------------------------
  nameEPIC = 'K2Campaign'+strTrim(string(campaign,format='(I)'),2)+'targets.csv'
  list = K2ReadTarget( conf.path.EPIC+nameEPIC )
  nbEpic = n_elements(list)


;-----------------------------------------------------------------------------------------------;
;-----------------------------------------------------------------------------------------------;
;---  TAG ---   II -- Dump Target Pixel Files                            -----------------------;
;-----------------------------------------------------------------------------------------------;
;-----------------------------------------------------------------------------------------------;
  for kEpic=0, nbEpic-1 do begin

   ;--II.1-- EPIC File Name  -------------------------------------------------------------------
    epicStr = strTrim(string(list[kEpic].epic,format='(I)'),2)
    nameLC = 'ktwo'+epicStr+'-'+campLoLab2+'_lpd-targ.fits'
    nameSC = 'ktwo'+epicStr+'-'+campLoLab2+'_spd-targ.fits'
    nameLCgz = nameLC+'.gz'
    nameSCgz = nameSC+'.gz'
      
   ;--II.2-- Progression Information  ----------------------------------------------------------
    if keyword_set(verbose) then print, kEpic, nbEpic, epicStr, format='(I6,2x,I6,2x,A-20)'

   ;--II.3-- Download Short Cadence  -----------------------------------------------------------
    if not (file_test(dirFITS+nameSC,/read) or file_test(dirFITS+nameSCgz,/read)) then  begin
      url = 'https://archive.stsci.edu/pub/k2/target_pixel_files/'+campLoLab1+'/'+$
            strMid(epicStr,0,4)+'00000/'+strMid(epicStr,4,2)+'000/'+nameSCgz
      spawn, 'wget --spider '+url, res, err
      if n_elements(err) eq 8 then spawn, 'wget -q '+url+' -O '+dirFITS+nameSCgz, res, err
    endif

   ;--II.4-- Download Long Cadence  ------------------------------------------------------------
    if not (file_test(dirFITS+nameLC,/read) or file_test(dirFITS+nameLCgz,/read)) then begin
      url = 'https://archive.stsci.edu/pub/k2/target_pixel_files/'+campLoLab1+'/'+$
            strMid(epicStr,0,4)+'00000/'+strMid(epicStr,4,2)+'000/'+nameLCgz
      spawn, 'wget --spider '+url, res, err
      if n_elements(err) eq 8 then spawn, 'wget -q '+url+' -O '+dirFITS+nameLCgz, res, err
    endif

  endfor    ;--II-- End of loop over EPIC identifiers


end