c********************************************************************
	
	SUBROUTINE tl_vkf(v,k,fesh,teff,ll)
	
c routine PUBLIC du module mod_photo
		
c calcul de la Teff en utilisant les Mv, Mk et [Fe/H]
c suivant Alonso et al. A&A 313, 873, 1996 (formules 7 et 8),
c de la luminosite L/Lsol avec la correction bolometrique
c suivant Alonso et al. A&A 297, 197, 1995 (formules 9 et 10)

c Auteur: P. Morel, Laboratoire Lagrange, O.C.A., CESAM2k

c entrees
c	v,k : magnitudes absolues V et K
c	fesh : [Fe/H]

c sorties
c	teff : Teff
c	ll : L/Lsol

c------------------------------------------------------------------------

	USE mod_kind
	
	IMPLICIT NONE
	
	REAL (kind=dp), INTENT(in) :: v, k, fesh
	REAL (kind=dp), INTENT(out) :: teff, ll		
	
	REAL (kind=dp), PARAMETER :: vmk_sol=1.486d0, bcv_sol=-0.07d0,
	1 mbol_sol=4.75d0
	REAL (kind=dp), SAVE :: phi_sol, cte2
	REAL (kind=dp) :: vmk, bc, phi1, phi2, bck, phi, dteff
	
	LOGICAL, SAVE :: init=.TRUE.	
	LOGICAL :: cas1, cas2, cas3
 	
c-----------------------------------------------------------------------
	
	phi1(vmk,fesh)=	2.38619d-4-1.01449d-5*fesh	!formule 9
	1 +vmk*( -1.93659d-4+8.17345d-6*fesh
	2 +vmk*(  6.52621d-5-2.87876d-6*fesh
	3 +vmk*( -7.95862d-6+5.40944d-7*fesh)))
	phi2(vmk,fesh)= 2.23403d-4-3.71945d-5*fesh	!formule 10
	1 +vmk*( -1.71897d-4+4.99847d-5*fesh
	2 +vmk*(  5.51085d-5-2.41517d-5*fesh
	3 +vmk*( -6.41071d-6+4.10655d-6*fesh)))
	
2000	FORMAT(8es10.3)

	IF(init)THEN	!initialisations
	 init=.FALSE.
	 
c	 vmk_sol=1.486d0	!Cayrel 1.48, Alonzo et al. prennent 1.486
c	 bcv_sol=-0.07d0	!Cayrel
c	 bcv_sol=-0.12d0	!Alonzo et al.	 
	 
	 phi_sol=phi1(vmk_sol,0.d0)
	 cte2=bcv_sol+vmk_sol+2.5d0*log10(phi_sol)
	 phi_sol=2.5*log10(phi_sol)
	 WRITE(*,10)
10	 FORMAT('calcul de la correction bolometrique et de L/Lsol',/,
	2 'suivant Alonso et al. A&A 297, 197, 1995 (formules 9 et 10)',/)
	ENDIF

	vmk=v-k	
c	WRITE(*,1)v,k,vmk,fesh
1	FORMAT('V=',f8.4,', K=',f8.4,', V-K=',f8.4,', [Fe/H]=',1pe10.3,/)

	CALL t_vkf(v,0.d0,k,0.d0,fesh,0.d0,teff,dteff)
	
c correction bolometrique et luminosite L/Lsol
	cas1=0.9d0 < vmk .AND. vmk <= 1.7d0
	cas2=1.7d0 < vmk .AND. vmk <= 2.9d0
	cas3=(0.8d0 < vmk .AND. vmk < 3.d0) .AND.
	1 (0.2d0 > fesh .AND.  fesh > -0.5d0)
	cas3=cas3 .or. (0.9d0 < vmk  .AND. vmk < 2.6d0) .AND.
	1 (-0.5d0 > fesh .AND. fesh > -1.5d0)
	cas3=cas3 .or. (1.1d0 < vmk .AND. vmk < 2.3d0) .AND.
	1 (-1.5d0 > fesh .AND. fesh > -2.5d0)
	cas3=cas3 .or. (1.2d0 < vmk .AND. vmk < 2.d0) .AND.
	1 (-2.5d0 > fesh .AND. fesh > -3.d0 )
	
	IF(cas1)then
	 phi=phi1(vmk,fesh)
	 IF(.NOT.cas3)WRITE(*,6)vmk,fesh
6	 FORMAT(1x,'utilisation des formules 9 et 11 bien que V-K=',es10.3,
	1	' et [Fe/H]=',es10.3)
	ELSEIF(cas2)then
	 phi=phi2(vmk,fesh)
	 IF(.NOT.cas3)WRITE(*,7)vmk,fesh
7	 FORMAT('utilisation des formules 10 et 11 bien que V-K=',es10.3,
	1 ' et [Fe/H]=',es10.3)
	ELSEIF(vmk < 0.9d0)then	 
	 phi=phi1(vmk,fesh)
	 IF(.NOT.cas3)WRITE(*,6)vmk,fesh	 
	ELSE
	 phi=phi2(vmk,fesh)
	 IF(.NOT.cas3)WRITE(*,7)vmk,fesh	
	ENDIF
	bc=-2.5d0*log10(phi)
	 	
	bck=bc+cte2

c luminosite en Lsol
	ll=10.d0**(-0.4d0*(k+bck-mbol_sol))
	
c	WRITE(*,12)lk,log10(lk)
12	FORMAT(1x,'L/Lsol deduite de K=',f8.3,', log L/Lsol=',1pe12.5)

	RETURN
		
	END SUBROUTINE tl_vkf