c********************************************************************
	
	SUBROUTINE t_byf(b,db,y,dy,fesh,dfesh,teff,dteff)
		
c calcul de la Teff en utilisant les Mb, My et [Fe/H]
c suivant Magain 1987 A&A 181, 323

c routine du module mod_photo

c Auteur: P. Morel, Laboratoire Lagrange, O.C.A., CESAM2k

c entrées
c	b, db, y, dy : magnitudes absolues b et y et erreurs
c	fesh, dfesh : [Fe/H] et erreur

c sorties
c	teff, dteff: Teff et erreur

c------------------------------------------------------------------------

	USE mod_kind
		
	IMPLICIT NONE
	
	REAL (kind=dp), INTENT(in) :: b, db, y, dy, fesh, dfesh 
	REAL (kind=dp), INTENT(out) :: teff, dteff

	REAL (kind=dp), SAVE :: ln10	
	REAL (kind=dp) :: bmy, dteff_bmy, dteff_fesh
	
	LOGICAL, SAVE :: init=.TRUE.

c-----------------------------------------------------------------------

	IF(init)THEN	!initialisations
	 init=.FALSE.
	 WRITE(*,10)
10	 FORMAT('calcul de la Teff à partir de b&y et [Fe/H]',/,
	1 '!!!!Attention!!!! pour naines de type solaire',
	2 'suivant Magain 1987 A&A 181, 323',/)
	
	 ln10=LOG(10.d0)	
	ENDIF

	bmy=b-y ; teff=8330.d0-7040.d0*bmy*(1.d0-0.099*10.d0**fesh)
	dteff_bmy=7040.d0*(1.d0-0.099*10.d0**fesh)
	dteff_fesh=7040.d0*bmy*0.099*10.d0**fesh*ln10
	dteff=sqrt(30.d0**2+(dteff_bmy*db)**2+(dteff_bmy*dy)**2+
	1	(dteff_fesh*dfesh)**2)	 
			
	RETURN
	
	END SUBROUTINE t_byf