c***********************************************************************

	SUBROUTINE dnu0_emp(m1,r1,teff1,dnu0,numax)

c routine du module mod_sismologie
	
c calcul de delta nu0 et de nu max empiriques
c formules de Kjeldsen & Bedding, 1995, A&A 293, 87

c entrées:
c	m1 : masse (Msol)
c	r1 : rayon (Rsol)
c	teff1 : Teff
c sorties:
c	dnu0 : deltanu0
c	numax : fréquence max

c Auteur: P. Morel, Département Lagrange, O.C.A., CESAM2k

c--------------------------------------------------------------------

	USE mod_donnees, ONLY : init_ctes_phys, teff_sol
	USE mod_kind
	
	IMPLICIT NONE
	
	REAL (kind=dp), INTENT(in) :: m1, r1, teff1
	REAL (kind=dp), INTENT(out) :: dnu0, numax		
	
	REAL (kind=dp), PARAMETER :: dnu0_sol=134.9d0, numax_sol=3.05d0
	REAL (kind=dp) :: m, r, teff
	
	
	LOGICAL, SAVE :: init=.TRUE.
	
c--------------------------------------------------------------------

	IF(init)THEN
	 init=.FALSE.
	 
c initialisation des constantes physiques en cohérence avec CESAM2k	 
	 CALL init_ctes_phys
	 
	ENDIF

	m=m1 ; r=r1 ; teff=teff1
	IF(m1*r1*teff1 <= 0.d0)THEN
	 WRITE(*,"('erreur dans appel a dnu0_emp, m=',es10.3,' r=',es10.3,
	1 ', Teff=',es10.3)")m1,r1,teff1
	 WRITE(*,"('on prend m=1, r=1, teff=Teff_sol')")
	 m=1.d0 ; r=1.d0 ; teff=teff_sol
	ENDIF  
	dnu0=SQRT(m/r**3)*dnu0_sol
	numax=m/r**2/SQRT(teff/teff_sol)*numax_sol

	RETURN
		
	END SUBROUTINE dnu0_emp