c**********************************************************************

	SUBROUTINE corr_bol_bess(t,l_g,ftg,dftgdt,dftgdg)

c subroutine PUBLIC du module mod_photo

c corrections bolométriques de Model atmospheres broad-band colors,
c bolometric corrections and temperature calibrations for O - M stars
c Bessell M.S., Castelli F., Plez B., 1998, A&A 333, 231

c adaptation P. Morel, Laboratoire Lagrange, O.C.A., CESAM2k
c interpolation en Teff,log_g

c entrées:
c	t, l_g : Teff, Log g

c sorties:
c	ftg: BC_K, BC_V, U_B, B_V etc...
c	dftgdt,dftgdg: derivees / Teff, Log g

c------------------------------------------------------------------

	USE mod_donnees, ONLY : nom_chemin
	USE mod_kind
	USE mod_numerique, ONLY : bsp2dn

	IMPLICIT NONE

	INTEGER, PARAMETER :: nt=22, ng=11, nf=10, mt=2, mg=2

	REAL (kind=dp), INTENT(in) :: t, l_g
	REAL (kind=dp), INTENT(out), DIMENSION(nf) :: ftg, dftgdt, dftgdg

	REAL (kind=dp), SAVE, DIMENSION(nf,nt,ng) :: data
 	INTEGER :: i
	REAL (kind=dp), PARAMETER, DIMENSION(nt) :: t_eff=
	1 (/ (3.5d3+2.5d2*i,i=0,nt-1) /)
	REAL (kind=dp), PARAMETER, DIMENSION(ng) :: log_g=
	1 (/ (0.5d0*i,i=0,ng-1) /)

	REAL (kind=dp), SAVE, DIMENSION(nt+mt) :: t_efft
	REAL (kind=dp), SAVE, DIMENSION(ng+mg) :: log_gt

	REAL (kind=dp) :: logg, BC_K, BC_V, U_B, B_V, V_R, V_I, V_K,
	1 J_H, J_K, K_L

 	INTEGER, SAVE :: knott, knotg, lt=mt, lg=mg
 	INTEGER :: j, teff

	LOGICAL :: init=.TRUE.

c------------------------------------------------------------------

2000	FORMAT(8es10.3)

	IF(init)THEN
	 init=.FALSE.
c	 PRINT*, TRIM(nom_chemin) ; PAUSE'corr_bol'
	 OPEN(unit=1,file=TRIM(nom_chemin)//'cor_bol_bessel.data',form='formatted')
	 DO j=1,ng
	  DO i=1,nt
           READ(1,2,END=3)teff,logg,
	1  BC_K,BC_V,U_B,B_V,V_R,V_I,V_K,J_H,J_K,K_L
2	   FORMAT(I5,1x,F4.2,1x,F5.2,1x,F5.2,1x,F6.3,1x,F6.3,1x,F6.3,
	1  1x,F6.3,1x,F6.3,1x,F6.3,1x,F6.3,1x,F4.1)
c	   write(*,2)teff,logg,BC_K,BC_V,U_B,B_V,V_R,V_I,V_K,J_H,J_K,K_L
           DATA(:,i,j)=(/ BC_K,BC_V,U_B,B_V,V_R,V_I,V_K,J_H,J_K,K_L /)
          ENDDO

         ENDDO
3        CLOSE(unit=1)

	 CALL bsp2dn(nf,data,t_eff,t_efft,nt,knott,mt,lt,
	1 log_g,log_gt,ng,knotg,mg,lg,.FALSE.,
	2 t_eff(1),log_g(1),ftg,dftgdt,dftgdg)
c	 write(*,2000)ftg ; write(*,2000)dftgdt	; write(*,2000)dftgdg

	 PRINT*
	 PRINT*,'bolometric corrections and temperature calibrations'
	 print*,'for O - M stars from Bessell M.S., Castelli F., Plez B'
	 PRINT*,'A&A 1998, BESSELL M.S., CASTELLI F., PLEZ B.'

	ENDIF

	CALL bsp2dn(nf,data,t_eff,t_efft,nt,knott,mt,lt,
	1 log_g,log_gt,ng,knotg,mg,lg,.TRUE.,
	2 t,l_g,ftg,dftgdt,dftgdg)

	RETURN

	END SUBROUTINE corr_bol_bess