!******************************************************************
      
      subroutine lim_t1(list,l,r,xchim,p,t,dpl,dpr,dtl,dtr,te,rtot,     &
     &     m,dml,dmr,p_atm,t_atm,m_atm,tau,r_atm,n_atm)
!     Version: 07-Jun-2004
      
!ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
!     Conditions limites externes a P=1bar, T=Teq+     c
!ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
      
!     Auteur: T.Guillot, Laboratoire Cassiopee, O.C.A., Observatoire de Nice
      
! Entrees:
!     list=.true. : on calcule p_atm,t_atm,r_atm,tau,m_atm    
!     l :luminosite
!     r :rayon
!     xchim : composition chimique
! Sorties:
!     p : pression
!     t : temperature
!     m : masse
!     dpl, dpr, dtl, dtr, dml, dmr : derivees p,t,m / l, r
!     teff : temperature effective
!     rtot : rayon externe
!     p_atm,t_atm,r_atm,tau,m_atm : sans objet
!     n_atm : mis a 0
! Table contenant la relation Te-T10: "data/Limites/modelx.dat"
!
! Correction du 1/7/98: 
!  DT/DR=T/R*(-2*dlnT/dlng + dlnT/dlnTe*1/2*(1/(L/(Lsol*R^2)+1) -1))
!  (1/(L/(Lsol*R^2)+1) au lieu de R/(L/Lsol+R^2))

!ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
! Attention: probleme de reinitialisation des variables cgrav cteff    c
!            sur DUPARC -> on les met en data                          c
!ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc

      implicit none
      
      include './cepam.inc'

      integer n_atm
      
      real*8 l,r,xchim(1),p,t,dpl,dpr,dtl,dtr,te,rtot,                  &
     &     m,dml,dmr,p_atm(1),t_atm(1),m_atm(1),tau(1),r_atm(1)
      logical list
      
      real*8 plim,lum_eq,leq_jup

      logical init
      data init /.true./
      
      include './Communs/ctephys.inc'
      include './Communs/planetes.inc'
      include './Communs/modelp.inc'

!------------S-----------A-----------V------------E--------------------
      save 
!----------------------------------------------------------------------

!ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
!     On tient compte de la luminosite solaire: teq dans common        c
!ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc

      if (init) then
       init=.false.
       plim=1.d6
       write(2,2)plim,teq
       write(*,2)plim,teq
 2     format(/,t5,'Conditions externes fixes',                         &
     &      /,' P=',1pd12.5,' dyn/cm2;  Tlim=',1pd12.5,' K',/)
       leq_jup=4*pi*rjup**2*(aradia*clight/4)*teq**4/ljup
       n_atm=0

      endif                     !--------------------------init---

      lum_eq=leq_jup*r*r
      p=plim
      t=teq*(1+l/lum_eq)**0.25
      dpl=0.d0
      dpr=0.d0
      dtl=0.25*teq/lum_eq*(1+l/lum_eq)**(-0.75)
      dtr=-0.5*teq/r*(l/lum_eq)*(1+l/lum_eq)**(-0.75)
      te=t
      rtot=r
      m=1.                      !raccord en masse a l'exterieur
      dml=0
      dmr=0
      
      return
      
      end